home *** CD-ROM | disk | FTP | other *** search
/ Amiga Format CD 42 / Amiga Format AFCD42 (Issue 126, Aug 1999).iso / -serious- / comms / other / ambos-update / ambos / wbstartup / loadambos next >
AmigaDOS Script File  |  1999-05-17  |  2KB  |  110 lines
  1. .key STACK/K,BBS/K,BACKUP/K
  2. .bra {
  3. .ket }
  4.  
  5. ; $VER: LoadAmBoS 1.2 (21.11.98) by SPOCK (spock@ebase.capella.de)
  6.  
  7. FailAt 21
  8.  
  9. ; ==============================
  10. ; === AmBoS already running? ===
  11. ; ==============================
  12. Lab CheckAmBoS
  13. Status >NIL: COM=BBS:AmBoS
  14. If not warn
  15.  RequestChoice >NIL: "LoadAmBoS Info" "AmBoS ist schon gestartet" "Ok"
  16.  Skip Ende
  17. EndIf
  18.  
  19. ; ===================================
  20. ; === Set / check BBS: assignment ===
  21. ; ===================================
  22.  
  23. If "{BBS}" not eq ""
  24.  Assign >NIL: BBS: remove
  25.  Assign >NIL: BBS: "{BBS}"
  26. EndIf
  27. Lab CheckBBS
  28. Assign >NIL: BBS: exists
  29. If warn
  30.  Set res `RequestChoice "LoadAmBoS Fehler" "Laufwerk BBS: nicht vorhanden" "Jetzt zuweisen" "Abbrechen"`
  31.  If $res EQ "0"
  32.   Skip Ende
  33.  EndIf
  34.  Assign >NIL: BBS: `RequestFile DRAWERSONLY TITLE "Verzeichnis für BBS:"`
  35.  Skip CheckBBS back
  36. EndIf
  37.  
  38. ; ======================================
  39. ; === Set / check Backup: assignment ===
  40. ; ======================================
  41.  
  42. If "{BACKUP}" not eq ""
  43.  Assign >NIL: Backup: remove
  44.  Assign >NIL: Backup: "{BACKUP}"
  45. EndIf
  46. Lab CheckBackup
  47. Assign >NIL: Backup: exists
  48. If warn
  49.  Set res `RequestChoice "LoadAmBoS Fehler" "Laufwerk Backup: nicht vorhanden" "Jetzt zuweisen" "Abbrechen"`
  50.  If $res EQ "0"
  51.   Skip Ende
  52.  EndIf
  53.  Assign >NIL: Backup: `RequestFile DRAWERSONLY TITLE "Verzeichnis für Backup:"`
  54.  Skip CheckBackup back
  55. EndIf
  56.  
  57. ; ==================
  58. ; === Check Font ===
  59. ; ==================
  60.  
  61. If exists FONTS:AmBoS.font
  62.  If exists FONTS:AmBoS/8
  63.   Skip FontOK
  64.  EndIf
  65. EndIf
  66. If exists BBS:Fonts/AmBoS.font
  67.  If exists BBS:Fonts/AmBoS/8
  68.   Assign FONTS: BBS:Fonts ADD
  69.   Skip FontOK
  70.  EndIf
  71. EndIf
  72. RequestChoice "LoadAmBoS Fehler" "AmBoS-Font nicht gefunden" "Abbruch"
  73. Skip Ende
  74. Lab FontOK
  75.  
  76. ; ======================
  77. ; === Set stack size ===
  78. ; ======================
  79.  
  80. If "{STACK}" not eq ""
  81.  set stacksize {STACK}
  82. Else
  83.  set stacksize 50000
  84. EndIf
  85. Stack >NIL: $stacksize
  86. If warn
  87.  RequestChoice >NIL: "LoadAmBoS Fehler" "Stack-Fehler: Speichermangel" "Abbruch"
  88.  Skip Ende
  89. EndIf
  90. unset stacksize
  91.  
  92. ; =================
  93. ; === Run AmBoS ===
  94. ; =================
  95.  
  96. If exists BBS:AmBoS
  97.  Run >NIL: BBS:AmBoS
  98.  Skip Ende
  99. EndIf
  100. If not exists SYS:WBStartup/AmBoS
  101.  RequestChoice >NIL: "LoadAmBoS Fehler" "Programm 'AmBoS' nicht zu finden" "Abbruch"
  102.  Skip Ende
  103. EndIf
  104. Run >NIL: SYS:WBStartup/AmBoS
  105.  
  106. Lab Ende
  107. Stack >NIL: 4096
  108. Unset res
  109.  
  110.